处理用户交互,本模块主要介绍了多点触摸相关功能的用法,包括触摸和手势。处理用户交互是AIR Android开发的基础部分,只有设计合理、用户操作符合逻辑的交互,才能增强程序的用户体验。因此,熟练掌握常见的交互手法至关重要。本文为大家介绍 触摸事件与鼠标事件的区别。
触摸事件与鼠标事件的区别
通过上一节的例子,可以看出触摸事件与鼠标有很多相似之处,唯一的区别在于,触摸事件可以是多点的,而鼠标事件总是单点的。如果程序并不需要使用多 点触摸的功能,而仅仅是传统的单点交互,那么使用鼠标事件就可以满足需求。
事实上,相比鼠标事件,AIR运行时会花费更多的资源去监听触控事件(包括下一节介绍的手势动作)。在运行TouchEventEx程序时,如果手 指在屏幕上的移动速度过快,圆点的移动会出现明显的延迟。
为了更清楚地说明两种事件的区别,可以使用MouseEvent重写TouchEventEx程序。修改之后的代码位于项目 MouseEventEx中,主程序Main.as如下:
package
{
import flash.display.Graphics;
import flash.display.Sprite;
import flash.events.MouseEvent;
public class Main extends AppBase
{
override protected function init():void
{
//改为监听MOUSE_DOWN和MOUSE_UP事件
stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDownHandler);
stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUpHandler);
}
/**
* 创建一个Sprite,画圆
*/
private function createCircle():Sprite
{
var box:Sprite = new Sprite();
var g:Graphics = box.graphics;
g.beginFill(0x808888);
g.drawCircle(0, 0, 30);
g.endFill();
return box;
}
private function onMouseDownHandler(e:MouseEvent):void
{
//在触摸点处添加一个圆
var box:Sprite = createCircle();
addChild(box);
//将元件移到触摸点对应的舞台坐标处
box.x = e.stageX;
box.y = e.stageY;
//开始拖拽元件
box.startDrag();
}
private function onMouseUpHandler(e:MouseEvent):void
{
//结束拖拽
e.target.stopDrag();
}
}
}
相信读者看了这部分代码后会感觉很熟悉,这里用到了鼠标事件MOUSE_DOWN和MOUSE_UP,以及startDrag和stopDrag, 这些都是Flash开发中常用的写法。
在真机上运行MouseEventEx,无论使用多少个手指同时触摸屏幕,程序总是只响应一次鼠标事件。另外,拖拽圆点时没有延迟感,明显比 TouchEventEx程序的运行效果要流畅。
提示使用MouseEvent还有一个好处,那就是代码能够兼容桌面系统。在开发跨平台的项目时,这点显得尤为重要,比如 MouseEventEx程序即可以在桌面上调试运行,也可以在模拟器上运行。